For Loop 키즈멧 노드 만들기

class SeqAct_ForLoop extends SequenceAction;

// 루프 시작으로 사용할 수치
var() int Start;
// 루프 끝으로 사용할 수치
var() int End;
// for 루프 증가분. 항상 양수 사용
var() int Increment;
// 이터레이팅에 끝 포함
var() bool IncludeEnd;
// 레벨 디자이너가 필요할 때 쓰는 Index 출력
var int Index;
// 내부 인덱스
var int InternalIndex;
// 내부 인덱스가 이전에 설정된 적이 있는지?
var bool HasSetInternalIndex;

event Activated()
{
  // 이터레이트할 범위가 있는지 검사
  if (Start == End || Increment <= 0)
  {
    return;
  }

  if (!HasSetInternalIndex)
  {
    InternalIndex = Start;
    HasSetInternalIndex = true;
  }

  if (Start < End)
  {
    Index = InternalIndex;

    if (InternalIndex < End || (IncludeEnd && InternalIndex <= End))
    {
      ActivateOutputLink(0);
      InternalIndex += Increment;
    }
    else
    {
      InternalIndex = Start;
    }
  }
  else if (Start > End)
  {
    Index = InternalIndex;

    if (InternalIndex > End || (IncludeEnd && InternalIndex >= End))
    {
      ActivateOutputLink(0);
      InternalIndex -= Increment;
    }
    else
    {
      InternalIndex = Start;
    }
  }
}

defaultproperties
{
  Increment=1
  InternalIndex=0
  bAutoActivateOutputLinks=false
  HasSetInternalIndex=false
  ObjName="For Loop"
  ObjCategory="Misc"
  InputLinks(0)=(LinkDesc="In")
  OutputLinks(0)=(LinkDesc="Out")
  VariableLinks.Empty
  VariableLinks(0)=(ExpectedType=class'SeqVar_Int',LinkDesc="Start",PropertyName=Start)
  VariableLinks(1)=(ExpectedType=class'SeqVar_Int',LinkDesc="End",PropertyName=End)
  VariableLinks(2)=(ExpectedType=class'SeqVar_Int',LinkDesc="Increment",bHidden=true,PropertyName=Increment)
  VariableLinks(3)=(ExpectedType=class'SeqVar_Int',LinkDesc="Index",bWriteable=true,PropertyName=Index)
}