物理マテリアル

/**
*  C++ ランドからの足音を立てろと告げるイベント。
**/
event PlayFootStepSound(int FootDown)
{
   local vector PawnLoc;
   local float CurrHeight;

   local Actor TraceActor;

   local vector out_HitLocation;
   local vector out_HitNormal;
   local vector TraceDest;
   local vector TraceStart;
   local vector TraceExtent;
   local TraceHitInfo HitInfo;

   // kk ここでは、tracez0r で下に下に地面の下まで追跡する必要があるぜ、ベイビー！
   // 注：　これは最終的には C++ ランドに移す予定。
   PawnLoc = self.Location;
   CurrHeight = self.GetCollisionHeight();

   TraceStart = PawnLoc;
   TraceDest = PawnLoc - ( Vect(0, 0, 1 ) * CurrHeight ) - Vect(0, 0, 15 );

   // トレース（追跡）ダウンして何の上に立っているかを見る。
   TraceActor = Trace( out_HitLocation, out_HitNormal, TraceDest, TraceStart, false, TraceExtent, HitInfo, true );

   //DrawPersistentDebugLine( TraceStart, TraceDest, 255, 0, 0 );

   if( TraceActor != none )
   {
      // 実際のサウンドをここでプレイ。
      ActuallyPlayFootStepSound( FootDown, HitInfo );
      MakeNoise( 0.1f, 'NOISETYPE_FootStep' );
   }
   // そうでないと何にもぶつからず空気をうつだけ。
   else
   {
   //   Log( " We are in the air" );
   }

}

/**
* こうすると、どのマテリアルの上に立っているかを見つけ出し、
* 的確な足音を出します。
* PhysicalMaterial ツリーを参照してスポーンさせる有効な効果を見つけます。
*見つからないときは、 .uc file にかかれた効果にデフォルトとして落ち着きます。
* その武器のために。
**/
function ActuallyPlayFootStepSound( int FootDown, TraceHitInfo HitInfo )
{
   local PhysicalMaterial ParentPhysMaterial;
   local SoundCue SC;
   local SoundCue FootStepSound;

   // XO5 HAX0R
   // 雨の中にいるのであれば、水の足音をプレイ。
   //注: 今のところ、テレインはトレースできるマテリアルを返さないため、こうしなければなりません。
   //if( IsTimerActive( 'DropRainDropsOnToPawn' ) == TRUE )
   if( bShouldPlayWetFootSteps == TRUE )
   {
      Self.PlaySound( SoundCue'FootSteps.SoundCues.Footsteps_Marcus_Water', FALSE, TRUE );
      return;
   }


   // もしも PhysicalMaterial がないときは、
   if( HitInfo.PhysMaterial != none )
   {
      FootStepSound = GetFootStepSound( HitInfo.PhysMaterial, FootDown );
   }
   else
   {
      // マテリアルがあるかチェック
      // マテリアルがなければ、デフォルトの PS_DefaultImpactEffect を使わなければなりません。
      if( HitInfo.Material != none )
      {
         FootStepSound = GetFootStepSound( HitInfo.Material.PhysMaterial, FootDown );
      }
      else
      {
         // いつも "デフォルトの足音" つまり dirt step （ドロの足音）をプレイ。
         Self.PlaySound( SoundCue'FootSteps.SoundCues.Footsteps_Marcus_Dirt', FALSE, TRUE );
         return;
      }
   }


   // ここでは "hierarchy"（階層） を参照して、もし適応するアトリビュート（要素）の中に見つからず、
   // 腹ペコの私たちに、コンテンツが何もデータを提供しない場合には、
   // 多分、何かしらのデフォルトをプレイするコードがあったほうがいいだろう。

   // PhysMaterial （物理マテリアル）が何もなければ。
   if( HitInfo.PhysMaterial != none )
   {
      ParentPhysMaterial = HitInfo.PhysMaterial.Parent;
   }
   // ここで、parent phys material （物理マテリアルの親）を設定。
   else
   {
      // material に phys material　があるかをチェック。
      if( HitInfo.Material.PhysMaterial != none )
      {
         ParentPhysMaterial = HitInfo.Material.PhysMaterial.Parent;
      }
      else
      {
         ParentPhysMaterial = none;
      }
   }


   // これはツリー上を、 parent が null か、 footstep sound が見つかるまでたどる。
   // その時点で、脱出（exception (例外)のケースです)。
   // しかし、 .uc ランドには例外というものは存在しない。
   while( ( FootStepSound != none )
      && ( ParentPhysMaterial != none )
      )
   {
      // parent （親）のデータをチェック。
      FootStepSound = GetFootStepSound( ParentPhysMaterial, FootDown );
      ParentPhysMaterial = ParentPhysMaterial.Parent;
   }


   // material based effect　（マテリアルベースの効果）を使用
   if( FootStepSound != none )
   {
      //Log( " Playing Sound: " $ FootStepSound );
      SC = FootStepSound;
   }
   // デフォルトの行動をとる。
   else
   {
      //Log( " Playing Default Sound" );
      SC = SoundCue'FootSteps.SoundCues.Footsteps_Marcus_Dirt';
   }

   Self.PlaySound( SC, FALSE, TRUE );
}


/**
*  現在の PhysicalMaterial （物理マテリアル）の Sound （サウンド）が valid （有効）かを確認。
**/
function SoundCue GetFootStepSound( PhysicalMaterial PMaterial, int FootDown )
{
   local SoundCue Retval;

   Retval = none;

   // 私たちの Specific properties （特定のプロパティ）が exists (見つかった）ので function （関数）を呼び出して脱出。
   //
   if( ( none != PMaterial )
      && ( none != PMaterial.PhysicalMaterialProperty )
      && ( none != WarPhysicalMaterialProperty(PMaterial.PhysicalMaterialProperty) )
      && ( none != WarPhysicalMaterialProperty(PMaterial.PhysicalMaterialProperty).WarPhysicalMaterialFootSteps )
      )
   {
      Retval = GetSpecificFootStepSound( WarPhysicalMaterialProperty(PMaterial.PhysicalMaterialProperty).WarPhysicalMaterialFootSteps, FootDown );
   }
   else
   {
      Retval = none;
   }

   return Retval;
}


/**
* それぞれの Object はこれを上書きし、参照されるObject に準じたデータを return (返す)。
* (例：.  GetSpecificFootStepSound は marcus でコールされたら、
* marcus footstep sound　をさがし、 locust （虫のバッタ）で コールされたら locust sound をさがす)
**/
function SoundCue GetSpecificFootStepSound( WarPhysicalMaterialFootSteps FootStepSounds, int FootDown )
{
   local SoundCue Retval;

   // 必要な計算その他を行う。
   Retval = None;

   return Retval;
}


e.g. in class BigOgre


function SoundCue GetSpecificFootStepSound( MyGamePhysicalMaterialFootSteps FootStepSounds, int FootDown )
{
   local SoundCue Retval;

   // 必要な計算その他を行う。
   Retval = SoundCue'FootSteps.SoundCues.Footsteps_Player_Dirt';  // あるいは、これを config にして、
値を .ini ファイルに保存して、非プログラマーが編集できるようにする。

   return Retval;
}